* Script to produce a 2-plot page with a Hovmuller of 925mb winds within
* the Caribbean along with a time series of rainfall at a specific location
* from April to Nov. for 2002.
* Purpose of script is to describe possible relationships between rain and 
* the meridional variability of wind components. Plots wind field hovmuller
* of meridional wind (shaded) and zonal wind (contour)along with GPCP point time series.

* ITEMS OF INTEREST IN THIS SCRIPT: a) multi-plots, b)hovmuller, c) time series, d) strings, e) contour colors

* reset GrADS and open data file; in this case I open daily rainfall
'reinit'
'sdfopen c:\testdata\netcdf\gpcpdaily.nc'

* set up GrADS virtual page in inches to determine the placement of the first plot (time series)
'set vpage 4 11 0 8.5'
'set grid off'
'set grads off'

* select time and geographic properties of the first plot
* t = 1917 for April 1, 2002 GPCP daily
'set t 1917 2117'
'set lon 282'
'set lat 18.5'

* set vertical range, contour mark, and contour color
'set cmark 0'
'set vrange 0 70'
'set ccolor 4'

* draw the plot
'd prcp'

* set string properties and 
'set strsiz 0.13 0.13'
'set string 4'
'draw string 2.5 8.2 2002 GPCPv2.0 Daily (mm/day)'
'set strsiz 0.17 0.17'
'draw string 3.35 7.45 (18.5N,78W)'

*close the open file without resetting GrADS settings
'close 1'

* repeat the process above, but for secondary rainfall data (pentad rather than daily)
'sdfopen c:\testdata\netcdf\gpcp.pentad.mean.nc'
'set vpage 4 11 0 8.5'
'set grads off'
* in this case, you must be familiar with the time steps of your dataset
'set t 1699 1741'
'set lon 282'
'set lat 18.5'
'set cmark 0'
'set vrange 0 70'
'set ccolor 2'
'set cthick 8'
'set xlab off'
'd precip'
'set strsiz 0.13 0.13'
'set string 2'
'draw string 2.5 8.0 2002 GPCPv2.0 Pentad (mm/day)'
'set strsiz 0.17 0.17'
'set string 1'
'draw string 3.35 7.45 (18.5N,78W)'

'close 1'



'sdfopen c:\testdata\netcdf\vwnd.mon.mean.nc'
'sdfopen c:\testdata\netcdf\uwnd.mon.mean.nc'

* steps below to produce the hovmuller plot where y or latitude is fixed from 12N-19N
* basically, produces a time longitude (Hovmuller) plot averaged from 12-19N ranging from 95W to 60W

'set vpage 0 6 0 8.5'
'set grads off'
'set xlab on'
'set t 649 660'
'set lon 265 300'
'set y 1'
'set tlsupp year'
'set gxout shaded'
'set csmooth on'
'd ave(vwnd,lat=12,lat=19)'
'set gxout contour'
'set cstyle 1'
'd ave(uwnd.2,lat=12,lat=19)'
'set strsiz 0.1 0.1'
'draw string 0.4 8.2 2002 monthly NCEP v-wind (shaded), u-wind (contour) (12N-19N)'
'run cbar'

'printim c:\testdata\RSMAS1.jpg gif x800 x600 white'